DEMO   ENGLISH   CONFIG (1.0)
  ROOTCAT   S.
  LEXENTRIES  (DEMO ENGLISH).
  RULES       (DEMO ENGLISH).
  TEMPLATES   (DEMO ENGLISH).
  GOVERNABLERELATIONS    SUBJ OBJ COMP.
  SEMANTICFUNCTIONS    ADJUNCT  TOPIC FOCUS.
  NONDISTRIBUTIVES.

----

DEMO   ENGLISH   RULES (1.0)


   S --> NP: (^ SUBJ)=!
	     (! CASE)=nom;
 	 { VP
 	  |VPaux}.

   VP --> V
	  (NP: (^ OBJ)=!
	       (! CASE)=acc)
 	  PP*:! $ (^ ADJUNCT).

   VPaux --> AUX
	     VP.

   NP --> (D)
 	  N
 	  PP*:! $ (^ ADJUNCT).

   PP --> P
	  NP:(^ OBJ)=!
	     (! CASE)=acc.


----
DEMO   ENGLISH   TEMPLATES (1.0)

   NOUN-SG(_P) = "template for singular nouns"
	  @(PRED _P)
	  @(NUM sg).

   PRED(_P) = "basic PRED with no arguments"
	  (^ PRED)='_P'.

   NUM(_V) = "assigns value to number feature"
	  (^ NUM)=_V.

   UP-OBJ = "annotation to assign object function"
	  
	  @(UP-GF OBJ).

   UP-GF(_GF) = "generic annotation to assign a grammatical function"
	  
	  (^ _GF)=!.

----
DEMO ENGLISH LEXICON (1.0)

is 	  AUX * (^ TENSE)=pres
		(^ ASPECT)=prog.

in 	  P *   (^PRED)='in<(^OBJ)>'
	        (^ OBJ PCASE)=in.

with 	  P *   (^PRED)='with<(^OBJ)>'
	        (^ OBJ PCASE)=with.

the 	  D *   (^SPEC)=def.

a 	  D *   (^SPEC)=indef
	        (^NUM)=sg.

girl 	  N *   (^PRED)='girl'
	        (^NUM)=sg.

girls 	  N *   (^PRED)='girl'
	        (^NUM)=pl.

monkey    N *   (^PRED)='monkey'
	        (^NUM)=sg.

banana 	  N *   (^PRED)='banana'
	        (^NUM)=sg.

orange 	  N *   @(NOUN-SG orange).

telescope N *   (^PRED)='telescope'
	        (^NUM)=sg.

park      N *   (^PRED)='park'
	        (^NUM)=sg.

sheep 	  N *   (^PRED)='sheep'.

devours   V *   (^PRED)='devour<(^ SUBJ)(^ OBJ)>'
	        (^ SUBJ NUM) =c sg
	        (^ SUBJ PERS)=  3
                (^ TENSE)=pres. 

devoured  V *   (^PRED)='devour<(^ SUBJ)(^ OBJ)>'
                (^ TENSE)=past.

saw 	  V *   (^PRED)='see<(^ SUBJ)(^ OBJ)>'
                (^ TENSE)=past.

laughed   V *   (^PRED)='laugh<(^ SUBJ)>'
                (^ TENSE)=past .

sleeping  V *   (^PRED)='sleep<(^ SUBJ)>'
	        (^ ASPECT)=c prog.

sleeps 	  V *   (^PRED)='sleep<(^ SUBJ)>'
	        (^ SUBJ NUM) =c sg
	        (^ SUBJ PERS)=  3
                (^ TENSE)=pres.

----