DEMO   ENGLISH   CONFIG (1.0)
  ROOTCAT   S.
  LEXENTRIES  (DEMO ENGLISH).
  RULES       (DEMO ENGLISH).
  TEMPLATES   (DEMO ENGLISH).
  GOVERNABLERELATIONS    SUBJ OBJ COMP OBL OBJ2.
  SEMANTICFUNCTIONS    ADJUNCT.
  NONDISTRIBUTIVES.

----

DEMO   ENGLISH   RULES (1.0)


   S --> (ADV: @ADJUNCT)
 	 NP: @UP-SUBJ
	     @(DOWN-CASE nom);
 	 { VP
 	  |VPaux}
	 "(PUNCT)".

   PUNCT --> { PERIOD
	   |EXCL}.

   VP --> V
 	  (NP: @UP-OBJ
	       @(DOWN-CASE acc))
 	  (NP: @UP-OBJ2
	       @(DOWN-CASE acc))
 	  { ADV: @ADJUNCT
 	   |PP: { @ADJUNCT
		 |@UP-OBL}}*.

   VPaux --> AUX
	     VP.

   NP --> { (D)
 	    (AP": @ADJUNCT")
 	    N
 	    PP*: @ADJUNCT
	   |PRON
	   |NAME}.

   AP --> (Amod": @ADJUNCT")
	  A.

   PP --> P
	  NP: @UP-OBJ
	     @(DOWN-CASE acc).


----


DEMO   ENGLISH   TEMPLATES (1.0)

   ADJECTIVE(_P) =
	  @(PRED _P).

   AMOD(_P) =
	  @(PRED _P).

   NAME(_P) = "proper name"
	  @(NOUN-SG _P)
	  ~(^ SPEC).

   PERS-PRON(_P) = "personal pronoun"
	  @(PRED _P)
	  (^ PRON-TYPE)=pers
	  ~(^ SPEC).

   NOUN-SG(_P) = "template for singular nouns"
	  @(PRED _P)
	  @(NUM sg).

   NOUN-PL(_P) = "template for plural nouns"
	  @(PRED _P)
	  @(NUM pl).

   PRED(_P) = "basic PRED with no arguments"
	  (^ PRED)='_P'.

   TNS-ASP(_T _A) =
	  @(TENSE _T)
	  @(ASPECT _A).

   PREPOSITION(_V) =
	  (^ PRED)='_V<(^OBJ)>'
	  (^ OBJ PCASE)=_V.

   SPEC(_V) =
	  (^ SPEC)=_V.

   V3SG = (^ SUBJ NUM) =sg
	  (^ SUBJ PERS)= 3.

   VPROG = @(TENSE pres)
	  (^ ASPECT)=c prog.

   V-NOT-3SG = 
	  { (^ SUBJ NUM) =sg
	    (^ SUBJ PERS)~=3
	   |(^ SUBJ PERS)= 3}.

   V-INTRANS(_P) =
	  (^PRED)='_P<(^ SUBJ)>'.

   V-TRANS(_P) = 
	  (^PRED)='_P<(^ SUBJ)(^ OBJ)>'.

   V-DITRANS(_P) = 
	  (^PRED)='_P<(^ SUBJ)(^ OBJ)(^ OBJ2)>'.
 
   V-OBL(_P _PREP) = 
	  (^PRED)='_P<(^ SUBJ)(^ OBL)>'
	  (^ OBL OBJ PCASE)=c _PREP.


   ASPECT(_V) = 
	  (^ ASPECT)=_V.

   TENSE(_V) = 
	  (^ TENSE)=_V.

   NUM(_V) = "assigns value to number feature"
	  (^ NUM)=_V.

   UP-OBJ = "annotation to assign object function"
	  @(UP-GF OBJ).

   UP-SUBJ = @(UP-GF SUBJ).

   UP-OBL = @(UP-GF OBL).

   UP-OBJ2 = @(UP-GF OBJ2).

   ADJUNCT = ! $ (^ ADJUNCT).

   DOWN-CASE(_V) = (! CASE)=_V.

   UP-CASE(_V) = (^ CASE)=_V.


   UP-GF(_GF) = "generic annotation to assign a grammatical function"
	  (^ _GF)=!.

----
DEMO ENGLISH LEXICON (1.0)

is 	  AUX * @(TNS-ASP pres prog).

in 	  P *   @(PREPOSITION in).

about 	  P *   @(PREPOSITION about).

with 	  P *   @(PREPOSITION with).

the 	  D *   @(SPEC def).

a 	  D *   @(SPEC indef)
	        @(NUM sg).

an 	  D *   @(SPEC indef)
	        @(NUM sg).

girl 	  N *   @(NOUN-SG girl).

purple 	  A * @(ADJECTIVE purple).

garden 	  N *   @(NOUN-SG garden).

girls 	  N *   @(NOUN-PL girl).

monkey    N *   @(NOUN-SG monkey).

banana 	  N *   @(NOUN-SG banana).

orange 	  N * @(NOUN-SG orange);
	  A * @(ADJECTIVE orange).

flimsy 	  A * @(ADJECTIVE flimsy).

very 	  Amod * @(AMOD very).

extremely Amod * @(AMOD extremely).

telescope N *   @(NOUN-SG telescope).

park      N *   @(NOUN-SG park).

sheep 	  N *   @(PRED sheep) { (^ NUM)=sg | (^ NUM)=pl}.

devours   V * @(V-TRANS devour)
	      @V3SG
	      @(TENSE pres). 

devoured  V *   @(V-TRANS devour)
                @(TENSE past).

devouring  V *   @(V-TRANS devour)
                @VPROG.

ate 	  V *   @(V-TRANS eat)
                @(TENSE past).

eats 	  V * @(V-TRANS eat)
	      @(TENSE pres)
	      @V3SG.

laughed   V * @(V-INTRANS laugh)
	      @(TENSE past).

sleeping  V *   @(V-INTRANS sleep)
                @VPROG.

sleeps 	  V *   @(V-INTRANS sleep)
	        @V3SG
                @(TENSE pres).

yesterday ADV * @(PRED yesterday).

today ADV * @(PRED today).

give 	  V * @(V-DITRANS give)
	      @V-NOT-3SG
	      @(TENSE pres).

gives 	  V * @(V-DITRANS give)
	      @V3SG
	      @(TENSE pres).

gave 	  V * @(V-DITRANS give)
	      @(TENSE past).
				   
giving 	  V * @(V-DITRANS give)
	      @VPROG.

thought   V * { @(V-OBL think about) | @(V-INTRANS think) }
	      @(TENSE past) .

Mary      NAME * @(NAME Mary).

she       PRON * @(PERS-PRON she) @(UP-CASE nom).

he       PRON * @(PERS-PRON he) @(UP-CASE nom).

`. PERIOD *.
! EXCL *.

----